#!/usr/bin/perl -w

=head1 NAME

dh_illumos_make - build illumos sources

=cut

use strict;
use Debian::Debhelper::Dh_Lib;

=head1 SYNOPSIS

B<dh_illumos_make> [S<I<debhelper options>>] [B<-m>I<make program>]
[B<-t>I<target>] [B<--debug>] [B<--without-ctf>]
[B<--no-onbld>] [B<--native>]
[directories]

=head1 DESCRIPTION

C<dh_illumos_make> is responsible for building illumos sources.
If no directories specified, it will build entire illumos gate (not recommended,
and probably will fail). If directories are given, it will build within those directories
in order. Illumos sources should be previously unpacked with L<dh_illumos_gate(1)>.

=head1 EXAMPLES

    dh_illumos_make -t install_h usr/src/uts is equivalent to

    ksh93 usr/bldenv.sh usr/env.sh -c "cd usr/src/uts && /usr/bin/make --sun install_h"


    dh_illumos_make -m /opt/SUNWspro/bin/dmake usr/src/lib is equivalent to

    ksh93 usr/bldenv.sh usr/env.sh -c "cd usr/src/lib && /opt/SUNWspro/bin/dmake install"


=head1 OPTIONS

=over 4

=item B<-m>I<make program> B<--make=>I<make program>

Make program to use. Default is F</usr/bin/make --sun>.

=item B<-t>I<target> B<--target=>I<target>

Target for I<make program>. Default is C<install> which will build
sources and install into proto area.

=item B<--debug>

Turn on debug build. This will execute 

    ksh93 usr/bldenv.sh -d usr/env.sh ...

instead of

    ksh93 usr/bldenv.sh usr/env.sh ...

=item B<--without-ctf>

Do not use CTF (I<Compact C Type Format>) tools during build.
Every ELF object built from illumos sources should be processed
by these tools, even F<libctf> itself. This option is useful
for bootstrapping when CTF tools are not available. This is
implemented by setting corresponding environment variables to ":".

=item B<--no-onbld>

Do not use C<onbld> tools installed in system (F</opt/onbld>). Normally it only works
and useful for building C<onbld> itself. Otherwise F<usr/src/tools>
must be unpacked and built before any other component.
If this option is given, F<bldenv.sh> is called with C<-t> option instead of C<+t>.

=item B<--native>

Some components have both 32- and 64-bit versions, others have no architecture
specific versions.  Such components assumed to be 32-bit, and on 64-bit system
it is incorrect. With this option C<dh_illumos_make> will build those
components using system native compiler.

=back

=head1 NOTES

If illumos sources were unpacked with L<dh_illumos_gate(1)>,
proto area is F<debian/tmp>.

=cut

$dh{'MAKE'} = '/usr/bin/make --sun';
$dh{'TARGET'} = 'install';
$dh{'WITHOUT_CTF'} = 0;
$dh{'NO_ONBLD'} = 0;

init(options => { 
    'make|m=s'    => \$dh{'MAKE'},
    'target|t=s'  => \$dh{'TARGET'},
    'debug'       => \$dh{'DEBUG'},
    'without-ctf' => \$dh{'WITHOUT_CTF'},
    'no-onbld'    => \$dh{'NO_ONBLD'},
    'native'      => \$dh{'NATIVE'},
});

my @dirs = ('usr/src');
if (@ARGV) {
    @dirs = @ARGV;
}

# Check whether all dirs exist before doing anything:
foreach (@dirs) {
    s,.*illumos-gate/+,,;
    if (! -d "$_") {
        error("`$_' does not exist or not a directory");
    }
}

# Build in each dir:
# Sanity checks:
foreach (qw/bldenv.sh env.sh/) {
    if (! -r "usr/$_") {
        error("`$_' not found under 'usr/'. Maybe illumos sources were not properly unpacked.")
    }
}

my $opts = '';
$opts .= '-d' if $dh{'DEBUG'};
my $onbld = $dh{'NO_ONBLD'} ? '-t' : '+t';
$opts .= $onbld;

my $override = '';
$override .= ' CTFCONVERT=:' if $dh{'WITHOUT_CTF'};
$override .= ' CTFMERGE=:' if $dh{'WITHOUT_CTF'};

if ($dh{'NATIVE'}) {
    my $deb_host_arch_cpu = `dpkg-architecture -qDEB_HOST_ARCH_CPU`;
    $override .= ' i386_XARCH=';
    $override .= " LDLIBS32='\$(LDLIBS_NATIVE)'";
    $override .= " MAPFILE.NGB='\$(MAPFILE.NGB_$deb_host_arch_cpu)'";
}

foreach (@dirs) {
    complex_doit(qq!ksh93 usr/bldenv.sh $opts usr/env.sh -c "cd $_ && $dh{'MAKE'} $dh{'TARGET'}$override"!);
}

=head1 SEE ALSO

L<debhelper(7)>, L<dh_illumos_gate(1)>.

=head1 AUTHOR

Igor Pashev <pashev.igor@gmail.com>

=cut