1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
|
# $NetBSD: plist-man.awk,v 1.5 2006/02/07 18:43:02 jlam Exp $
#
# Copyright (c) 2006 The NetBSD Foundation, Inc.
# All rights reserved.
#
# This code is derived from software contributed to The NetBSD Foundation
# by Johnny C. Lam.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
# 1. Redistributions of source code must retain the above copyright
# notice, this list of conditions and the following disclaimer.
# 2. Redistributions in binary form must reproduce the above copyright
# notice, this list of conditions and the following disclaimer in the
# documentation and/or other materials provided with the distribution.
# 3. All advertising materials mentioning features or use of this software
# must display the following acknowledgement:
# This product includes software developed by the NetBSD
# Foundation, Inc. and its contributors.
# 4. Neither the name of The NetBSD Foundation nor the names of its
# contributors may be used to endorse or promote products derived
# from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
# POSSIBILITY OF SUCH DAMAGE.
### This awk script handles man page entries in PLISTs. This script
### requires the following scripts to be included:
###
### plist-functions.awk (print_entry)
###
### Certain environment variables must be set prior to running this script:
###
### IMAKE_MANINSTALL specifies how imake-using packages install man pages.
### Valid values are:
###
### no value the package doesn't use imake
### maninstall the package installed man pages
### catinstall the package installed catman pages
###
### Both "maninstall" and "catinstall" may be specified.
###
### MANINSTALL specifies if man pages are installed by the package.
### Valid values are:
###
### maninstall the package installed man pages
### catinstall the package installed catman pages
###
### Both "maninstall" and "catinstall" may be specified.
###
### MANZ is a yes/no variable that determines whether the man pages
### should be recorded as compressed or not.
###
### PKGMANDIR is the ${PREFIX}-relative path to the installed man pages.
###
BEGIN {
IMAKE_MANINSTALL = ENVIRON["IMAKE_MANINSTALL"] ? ENVIRON["IMAKE_MANINSTALL"] : "maninstall catinstall"
MANINSTALL = ENVIRON["MANINSTALL"] ? ENVIRON["MANINSTALL"] : "maninstall catinstall"
MANZ = ENVIRON["MANZ"] ? ENVIRON["MANZ"] : "no"
PKGMANDIR = ENVIRON["PKGMANDIR"] ? ENVIRON["PKGMANDIR"] : "man"
}
###
### Canonicalize man page entries by stripping any ".gz" suffixes.
###
/^[^@]/ && \
/^([^\/]*\/)+(man[1-9ln]\/[^\/]*\.[1-9ln]|cat[1-9ln]\/[^\/]*\.[0-9])\.gz$/ {
sub("\\.gz$", "")
}
###
### Rewrite "imake-installed" catman pages as man pages if imake only
### supports man pages.
###
(IMAKE_MANINSTALL == "maninstall") && /^[^@]/ && \
/^([^\/]*\/)+cat[1-9ln]\/[^\/]*\.[0-9ln]$/ {
n = split($0, components, "/")
sub("cat", "man", components[n-1])
section = substr(components[n-1], 4, 1)
sub("[0-9ln]$", section, components[n])
$0 = join(components, 1, n, "/")
}
(IMAKE_MANINSTALL == "maninstall") && \
/^@dirrm ([^\/]*\/)+cat[1-9ln]/ {
next
}
###
### Rewrite "imake-installed" man pages as catman pages if imake only
### supports catman pages.
###
(IMAKE_MANINSTALL == "catinstall") && /^[^@]/ && \
/^([^\/]*\/)+man[1-9ln]\/[^\/]*\.[0-9ln]$/ {
n = split($0, components, "/")
sub("man", "cat", components[n-1])
section = "0"
sub("[0-9ln]$", section, components[n])
$0 = join(components, 1, n, "/")
}
(IMAKE_MANINSTALL == "catinstall") && \
/^@dirrm ([^\/]*\/)+man[1-9ln]/ {
next
}
###
### If MANINSTALL doesn't contain "maninstall", then strip out man page
### entries from the PLIST, and similarly for "catinstall" and catman page
### entries.
###
(MANINSTALL !~ /catinstall/) && /^[^@]/ && \
/^([^\/]*\/)+cat[1-9ln]\/[^\/]*\.[0-9ln]$/ {
next
}
(MANINSTALL !~ /maninstall/) && /^[^@]/ && \
/^([^\/]*\/)+man[1-9ln]\/[^\/]*\.[0-9ln]$/ {
next
}
###
### Append ".gz" to the end of man page entries if compressed pages are
### requested.
###
(MANZ ~ /[yY][eE][sS]/) && /^[^@]/ && \
/^([^\/]*\/)+(man[1-9ln]\/[^\/]*\.[1-9ln]|cat[1-9ln]\/[^\/]*\.[0-9])$/ {
$0 = $0 ".gz"
}
###
### Convert man/ to ${PKGMANDIR}/ for all man and catman page entries.
###
/^[^@]/ && \
/^man\/([^\/]*\/)?(man[1-9ln]\/[^\/]*\.[1-9ln]|cat[1-9ln]\/[^\/]*\.[0-9])/ {
sub("^man/", PKGMANDIR "/")
}
/^@dirrm man\/([^\/]*\/)?(man[1-9ln]|cat[1-9ln])/ {
sub("^@dirrm man/", "@dirrm " PKGMANDIR "/")
}
|
