1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
|
#!/usr/bin/perl
=head1 NAME
combine - combine the lines in two files using boolean operations
=head1 SYNOPSIS
combine file1 and file2
combine file1 not file2
combine file1 or file2
combine file1 xor file2
_ file1 and file2 _
_ file1 not file2 _
_ file1 or file2 _
_ file1 xor file2 _
=head1 DESCRIPTION
B<combine> conbines the lines in two files. Depending on the boolean
operation specified, the contents will be combined in different ways:
=over 4
=item and
Outputs lines that are common to both files.
=item not
Outputs lines that are in file1 but not in file2.
=item or
Outputs lines that are in file1 or file2.
=item xor
Outputs lines that are in either file1 or file2, but not in both files.
=back
"-" can be specified for either file to read stdin for that file.
The input files need not be sorted, and the lines are output in the order
they accur in file1 (or file2 for the two "or" operations).
Note that this program can be installed as "_" to allow for the syntactic
sugar shown in the latter half of the synopsis (similar to the test/[
command). It is not currently installed as "_" by default.
=head1 AUTHOR
Copyright 2006 by Joey Hess <joey@kitenet.net>
Licensed under the GNU GPL.
=cut
use warnings;
use strict;
sub filemap {
my $file=shift;
my $sub=shift;
open (IN, $file) || die "$file: $!\n";
while (<IN>) {
chomp;
$sub->();
}
close IN;
}
sub hashify {
my $file=shift;
my %seen;
filemap $file, sub { $seen{$_}++ };
return \%seen;
}
sub compare_or {
my ($file1, $file2) = @_;
my $seen;
filemap $file1, sub { print "$_\n"; $seen->{$_}++ };
filemap $file2, sub { print "$_\n" unless $seen->{$_} };
}
sub compare_xor {
my ($file1, $file2) = @_;
compare_not($file1, $file2);
compare_not($file2, $file1);
}
sub compare_not {
my ($file1, $file2) = @_;
my $seen=hashify($file2);
filemap $file1, sub { print "$_\n" unless $seen->{$_} };
}
sub compare_and {
my ($file1, $file2) = @_;
my $seen=hashify($file2);
filemap $file1, sub { print "$_\n" if $seen->{$_} };
}
if (@ARGV >= 4 && $ARGV[3] eq "_") {
delete $ARGV[3];
}
if (@ARGV != 3) {
die "usage: combine file1 OP file2\n";
}
my $file1=shift;
my $op=shift;
my $file2=shift;
if ($::{"compare_$op"}) {
no strict 'refs';
"compare_$op"->($file1, $file2);
}
else {
die "unknown operation, $op\n";
}
|
