1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
|
{
x86 surface clear routines for HERMES
Copyright (c) 1998 Christian Nentwich (c.nentwich@cs.ucl.ac.uk)
This library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version
with the following modification:
As a special exception, the copyright holders of this library give you
permission to link this library with independent modules to produce an
executable, regardless of the license terms of these independent modules,and
to copy and distribute the resulting executable under terms of your choice,
provided that you also meet, for each linked independent module, the terms
and conditions of the license of that module. An independent module is a
module which is not derived from or based on this library. If you modify
this library, you may extend this exception to your version of the library,
but you are not obligated to do so. If you do not wish to do so, delete this
exception statement from your version.
This library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
(04/10/99) Modified ClearX86_8 <Mikko.Tiihonen@hut.fi>
}
{$ASMMODE att}
{
--------------------------------------------------------------------------
HermesClearInterface (ebp+..)
0: char8 *dest
4: int32 value
8: unsigned int width (already checked to be >0!)
12: unsigned int height (already checked to be >0!)
16: int add
}
procedure ClearX86_32(hci: PHermesClearInterface); cdecl; assembler;
asm
pushl %ebp
movl 8(%ebp),%ebp
movl (%ebp),%edi // destination
movl 4(%ebp),%eax // pixel value
movl 12(%ebp),%edx // height
.balign 4
.L_y:
movl 8(%ebp),%ecx
rep
stosl
addl 16(%ebp),%edi
decl %edx
jnz .L_y
popl %ebp
end;
procedure ClearX86_24(hci: PHermesClearInterface); cdecl; assembler;
asm
end;
procedure ClearX86_16(hci: PHermesClearInterface); cdecl; assembler;
asm
pushl %ebp
movl 8(%ebp),%ebp
movl (%ebp),%edi // destination
movl 4(%ebp),%eax // pixel value
movl 12(%ebp),%edx // height
movl %eax,%ebx
shll $16,%eax // Duplicate pixel value
andl $0x0ffff,%ebx
orl %ebx,%eax
.L_y:
movl 8(%ebp),%ecx
testl $3,%edi // Check if destination is aligned mod 4
jz .L_aligned
movw %ax,(%edi) // otherwise write one pixel
addl $2,%edi
decl %ecx
jz .L_endline
.L_aligned:
shrl $1,%ecx
rep
stosl
jnc .L_endline
movw %ax,(%edi)
addl $2,%edi
.L_endline:
addl 16(%ebp),%edi
decl %edx
jnz .L_y
popl %ebp
end;
procedure ClearX86_8(hci: PHermesClearInterface); cdecl; nostackframe; assembler;
asm
pushl %ebp
movl %esp,%ebp
movl 8(%ebp),%ebp
movl 4(%ebp),%eax // pixel value
movl 12(%ebp),%edx // height
movb %al,%ah
movl (%ebp),%edi // destination
movl %eax,%ecx
shll $16,%eax // Put the byte pixel value in all four bytes
andl $0x0ffff,%ecx // of eax
movl 8(%ebp),%ebx
orl %ecx,%eax
cmpl $5,%ebx // removes need for extra checks later
jbe .L_short_y
.balign 4
.L_y:
testl $3,%edi
jz .L_aligned
movl %edi,%ecx
negl %ecx
andl $3,%ecx
subl %ecx,%ebx
rep
stosb
.L_aligned:
movl %ebx,%ecx
shrl $2,%ecx
andl $3,%ebx
rep
stosl
movl %ebx,%ecx
rep
stosb
addl 16(%ebp),%edi
decl %edx
movl 8(%ebp),%ebx
jnz .L_y
popl %ebp
ret
// Short loop
.balign 4
.L_short_y:
movl %ebx,%ecx
rep
stosb
addl 16(%ebp),%edi
decl %edx
jnz .L_short_y
popl %ebp
end;
{
ClearX86_8 version 2,
Im not sure wheather this is faster or not...
too many jumps could confuse the CPU branch guessing
}
procedure ClearX86_8_2(hci: PHermesClearInterface); cdecl; nostackframe; assembler;
asm
pushl %ebp
movl %esp,%ebp
movl 8(%ebp),%ebp
movl 4(%ebp),%eax // pixel value
movl 12(%ebp),%edx // height
movb %al,%ah
movl (%ebp),%edi // destination
movl %eax,%ecx
shll $16,%eax // Put the byte pixel value in all four bytes
andl $0x0ffff,%ecx // of eax
movl 8(%ebp),%ebx
orl %ecx,%eax
cmpl $5,%ebx // removes need for extra checks in main loop
jbe .L_short_y
.balign 4
.L_y:
testl $3,%edi
jz .L_aligned
movl %edi,%ecx
negl %ecx
andl $3,%ecx
movb %al,(%edi)
subl %ecx,%ebx
incl %edi
decl %ecx
jz .L_aligned
movb %al,(%edi)
incl %edi
decl %ecx
jz .L_aligned
movb %al,(%edi)
incl %edi
.L_aligned:
movl %ebx,%ecx
shrl $2,%ecx
andl $3,%ebx
rep
stosl
jz .L_endline
// ebx
movb %al,(%edi)
// Write remaining (1,2 or 3) pixels
incl %edi
decl %ebx
jz .L_endline
movb %al,(%edi)
incl %edi
decl %ebx
jz .L_endline
movb %al,(%edi)
incl %edi
decl %ebx
jz .L_endline
movb %al,(%edi)
incl %edi
.L_endline:
addl 16(%ebp),%edi
decl %edx
movl 8(%ebp),%ebx
jnz .L_y
popl %ebp
ret
// Short loop
.balign 4
.L_short_y:
movl %ebx,%ecx
rep
stosb
addl 16(%ebp),%edi
decl %edx
jnz .L_short_y
popl %ebp
end;
|
