blob: 222968cee4e30ee72caeba0806009ea8da35b90a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
|
#!/usr/bin/perl
=head1 NAME
dh_installdirs - create subdirectories in package build directories
=cut
use strict;
use warnings;
use Debian::Debhelper::Dh_Lib;
=head1 SYNOPSIS
B<dh_installdirs> [S<I<debhelper options>>] [B<-A>] [S<I<dir> ...>]
=head1 DESCRIPTION
B<dh_installdirs> is a debhelper program that is responsible for creating
subdirectories in package build directories.
Many packages can get away with omitting the call to B<dh_installdirs>
completely. Notably, other B<dh_*> commands are expected to create
directories as needed.
=head1 FILES
=over 4
=item debian/I<package>.dirs
Lists directories to be created in I<package>.
Generally, there is no need to list directories created by the
upstream build system or directories needed by other B<debhelper>
commands.
=back
=head1 OPTIONS
=over 4
=item B<-A>, B<--all>
Create any directories specified by command line parameters in ALL packages
acted on, not just the first.
=item I<dir> ...
Create these directories in the package build directory of the first
package acted on. (Or in all packages if B<-A> is specified.)
=back
=cut
init();
# PROMISE: DH NOOP WITHOUT dirs
foreach my $package (@{$dh{DOPACKAGES}}) {
my $tmp=tmpdir($package);
my $file=pkgfile($package,"dirs");
install_dir($tmp) if compat(10);
my @dirs;
if ($file) {
@dirs=filearray($file)
}
if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
push @dirs, @ARGV;
}
if (@dirs) {
# Stick the $tmp onto the front of all the dirs.
# This is necessary, for 2 reasons, one to make them
# be in the right directory, but more importantly, it
# protects against the danger of absolute dirs being
# specified.
@dirs=map {
$_="$tmp/$_";
tr:/:/:s; # just beautification.
$_
} @dirs;
# Create dirs.
install_dir(@dirs);
}
}
=head1 SEE ALSO
L<debhelper(7)>
This program is a part of debhelper.
=head1 AUTHOR
Joey Hess <joeyh@debian.org>
=cut
|
