1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
/*
* CDDL HEADER START
*
* The contents of this file are subject to the terms of the
* Common Development and Distribution License (the "License").
* You may not use this file except in compliance with the License.
*
* You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
* or http://www.opensolaris.org/os/licensing.
* See the License for the specific language governing permissions
* and limitations under the License.
*
* When distributing Covered Code, include this CDDL HEADER in each
* file and include the License file at usr/src/OPENSOLARIS.LICENSE.
* If applicable, add the following below this CDDL HEADER, with the
* fields enclosed by brackets "[]" replaced with your own identifying
* information: Portions Copyright [yyyy] [name of copyright owner]
*
* CDDL HEADER END
*/
/*
* Copyright 2008 Sun Microsystems, Inc. All rights reserved.
* Use is subject to license terms.
*/
.file "memccpy.s"
#include <sys/asm_linkage.h>
ANSI_PRAGMA_WEAK(memccpy,function)
ENTRY(memccpy) /* (void *dst, void *src, uchar_t c, size_t) */
.loop:
decq %rcx / decrement bytes to go
jl .notfound
movb (%rsi),%dh
movb %dh,(%rdi) / move byte
cmpb %dh,%dl / is it the byte sought?
je .found / yes
decq %rcx / decrement bytes to go
jl .notfound
movb 1(%rsi),%dh
movb %dh,1(%rdi) / move byte
cmpb %dh,%dl / is it the byte sought?
je .found1 / yes
decq %rcx / decrement bytes to go
jl .notfound
movb 2(%rsi),%dh
movb %dh,2(%rdi) / move byte
cmpb %dh,%dl / is it the byte sought?
je .found2 / yes
decq %rcx / decrement bytes to go
jl .notfound
movb 3(%rsi),%dh
movb %dh,3(%rdi) / move byte
addq $4,%rsi
addq $4,%rdi
cmpb %dh,%dl / is it the byte sought?
jne .loop / no
decq %rdi
.found:
incq %rdi / return pointer to next byte in dest
movq %rdi,%rax
ret
.align 4
.found2:
incq %rdi
.found1:
addq $2,%rdi / return pointer to next byte in dest
movq %rdi,%rax
ret
.align 4
.notfound:
xorl %eax,%eax / search fails
ret
SET_SIZE(memccpy)
|
